VMServiceTemplate/terraform/modules/proxmox_ubuntu_cloudinit_clone/main.tf

resource "proxmox_virtual_environment_file" "cloud_config" {
  content_type = "snippets"
  datastore_id = "hlst"
  node_name    = var.node_name

  source_raw {
    file_name = "${var.vm_name}_vm.cloud-config.yaml"
    data      = <<-EOF
    #cloud-config
    hostname: ${var.vm_name}

    package_update: true
    package_upgrade: true

    system_info:
      default_user:
        groups: [ cloud ]

    users:
      - default
      - name: cloud
        groups:
          - sudo
          - docker
        shell: /bin/bash
        ssh-authorized-keys:
          - "${var.vm_user_sshkey}"
        sudo: ALL=(ALL) NOPASSWD:ALL

    packages:
      - qemu-guest-agent
      - apt-transport-https
      - ca-certificates
      - curl
      - gnupg
      - lsb-release
      - unattended-upgrades
      - rsync
      - nano

    bootcmd:
      - mkdir -p /home/cloud/${var.service_name}
      - chown cloud:cloud /home/cloud/${var.service_name}

    write_files:
      - path: /home/cloud/${var.service_name}/docker-compose.yml
        owner: cloud:cloud
        permissions: '0644'
        encoding: b64
        content: ${var.compose_file_content}

      - path: /home/cloud/${var.service_name}/.env
        owner: cloud:cloud
        permissions: '0600'
        encoding: b64
        content: ${var.env_file_content}

    runcmd:
      - systemctl enable qemu-guest-agent
      - mkdir -p /etc/apt/keyrings
      - apt-add-repository ppa:fish-shell/release-3
      - curl -fsSL https://download.docker.com/linux/ubuntu/gpg | gpg --dearmor -o /etc/apt/keyrings/docker.gpg
      - echo "deb [arch=$(dpkg --print-architecture) signed-by=/etc/apt/keyrings/docker.gpg] https://download.docker.com/linux/ubuntu $(lsb_release -cs) stable" | tee /etc/apt/sources.list.d/docker.list > /dev/null
      - apt-get update
      - apt-get install -y docker-ce docker-ce-cli containerd.io docker-compose-plugin fish
      - systemctl enable docker
      - systemctl start docker
      - chown -R cloud:cloud /home/cloud/${var.service_name}
      - cd /home/cloud/${var.service_name}
      - sudo -u cloud docker compose up -d
      - reboot
    EOF
  }
}

resource "proxmox_virtual_environment_vm" "ubuntu_22_minimal_clone" {
  name      = var.vm_name   # VM name
  node_name = var.node_name # Proxmox node to deploy the VM
  tags      = var.vm_tags   # Optional VM tags for categorization

  agent {
    enabled = true # Enable the QEMU guest agent
  }

  stop_on_destroy = true # Ensure VM is stopped gracefully when destroyed


  clone {
    vm_id     = local.selected_instance.vmid        # ID of the source template
    node_name = local.selected_instance.crispy_name # Node of the source template
  }

  bios    = var.vm_bios    # BIOS type (e.g., seabios or ovmf)
  machine = var.vm_machine # Machine type (e.g., q35)

  cpu {
    cores = var.vm_cpu # Number of CPU cores
    type  = "host"     # Use host CPU type for best compatibility/performance
  }

  memory {
    dedicated = var.vm_ram # RAM in MB
  }

  disk {
    datastore_id = var.node_datastore # Datastore to hold the disk
    interface    = "scsi0"            # Primary disk interface
    size         = var.vm_size
  }


  initialization {
    user_data_file_id = proxmox_virtual_environment_file.cloud_config.id # Link the cloud-init file
    datastore_id      = var.node_datastore
    interface         = "scsi1" # Separate interface for cloud-init
    ip_config {
      ipv4 {
        address = "dhcp" # Get IP via DHCP
      }
    }
  }

  network_device {
    bridge = var.bridge # Use the default bridge 
  }

  lifecycle {
    ignore_changes = [ # Ignore initialization section after first depoloyment for idempotency
      initialization
    ]
  }
}